ASP的Escape和UnEscape函數

昨天一個客戶的網站(zhàn)改點東西．本來(lái)很簡單的啦．沒想在幻燈片那兒卡死了．一般來(lái)說(shuō)幻燈片換個樣式百度一下一大(dà)堆．不過換上去(qù)了毛病卻出來(lái)了．先是不正常顯示．然後接着就(jiù)是點不了鏈接．郁悶了好久．後來(lái)問(wèn)我們技術(shù)部主管．嘿嘿．一次性解決問(wèn)題．

先看(kàn)下．原本的連接是這樣：Abcde.asp?mmid=025&lw=025&m2=1&t=245；我把這個鏈接直接放(fàng)到地址欄裡(lǐ)打開了．再返回去(qù)點幻燈片的．可(kě)以了．不過隻打開了Abcde.asp?mmid=025．我還(hái)以爲幻燈不支持&這個符号．所以折騰了好久．解決這個其它很簡單．轉碼一下就(jiù)ＯＫ了．

Function vbsEscape(str)
    dim i,s,c,a
    s=""
    For i=1 to Len(str)
        c=Mid(str,i,1)
        a=ASCW(c)
        If (a>=48 and a<=57) or (a>=65 and a<=90) or (a>=97 and a<=122) Then
            s = s & c
        ElseIf InStr("@*_+-./",c)>0 Then
            s = s & c
        ElseIf a>0 and a<16 Then
            s = s & "%0" & Hex(a)
        ElseIf a>=16 and a<256 Then
            s = s & "%" & Hex(a)
        Else
            s = s & "%u" & Hex(a)
        End If
    Next
    vbsEscape = s
End Function

Function vbsUnEscape(str)
    dim i,s,c
    s=""
    For i=1 to Len(str)
        c=Mid(str,i,1)
        If Mid(str,i,2)="%u" and i<=Len(str)-5 Then
            If IsNumeric("&H" & Mid(str,i+2,4)) Then
                s = s & CHRW(CInt("&H" & Mid(str,i+2,4)))
                i = i+5
            Else
                s = s & c
            End If
        ElseIf c="%" and i<=Len(str)-2 Then
            If IsNumeric("&H" & Mid(str,i+1,2)) Then
                s = s & CHRW(CInt("&H" & Mid(str,i+1,2)))
                i = i+2
            Else
                s = s & c
            End If
        Else
            s = s & c
        End If
    Next
    vbsUnEscape = s
End Function

然後再調用就(jiù)ＯＫ了